[TAC] Diskussion der Download- und Installationsangebote

[melcher kürzer]

Natürlich gibt's rechteckige Icons. Hier Beispiele von meinem Desktop:

Okay, okay. Ich sollte nicht immer so verallgemeinern. Trotzdem empfinde ich persönlich solche Icons als unprofessionell und unpassend. Das wirkt irgendwie "billig".

Da gab's zwar das technische Problem, das halbtransparente Stellen nicht korrekt angezeigt wurden, aber grundsätzlich konnte ich mit Gimp ein solches nicht-rechteckiges Icon erstellen. Ihr hattet ja den Screenshot gesehen.

Halbtranzparenz kann nicht funktionieren, da dieses Format das anscheindend nicht unterstützt.
Wie sieht das Icon denn in anderen Ansichten aus? Also z.B. in der Taskleiste (wenn das Spiel gestartet ist) oder im Explorer?

Aber als ich dann das Batman-Icon noch mal sah, dachte ich mir: "Wow! Schlicht und schön." Und daraufhin habe ich bewusst ein Icon mit einem rechteckigen Hintergrund erstellt. Ich finde, das gibt der Endlosigkeit eines Abendhimmels einen schönen Rahmen.

Naja, ich finde halt ein Icon sollte ein Symbol sein und kein kleines Bild. Mir ist das Motiv außerdem zu kitschig.
Aber mir ist es egal, macht wie ihr wollt, ich muss es ja nicht verwenden.

Edit:

Du kannst deine Icons aber ganz einfach selber ausprobieren. Bei einer beliebigen Verknüpfung unter Eigenschaften den Menüpunkt "anderes Symbol" auswählen und auf deine Datei verweisen.

Bei mir funktioniert das nicht. Ich bekomme eine Fehlermeldung:

"Die Datei c:\....\Desktop_Icon_Statue_v.01.ico enthält keine Symbole.
Wählen sie ein Symbol in der Liste, oder geben sie eine andere Datei an."

Ich wollte W.B.s Icons testen, aber sie funktionieren nicht bei mir.

[Writing Bull]

Ich sollte nicht immer so verallgemeinern.

Und schon wieder!

Achtung Spoiler:

Sorry, ich habe mich sehr bemüht, mir das zu verkneifen, aber hab's dann nicht geschafft.

[melcher kürzer]

Und schon wieder!

Achtung Spoiler:

Sorry, ich habe mich sehr bemüht, mir das zu verkneifen, aber hab's dann nicht geschafft.

Ich spreche doch nur von meiner persönlichen Meinung, sehe da keine Verallgemeinnerung.

Erklär mir lieber mal warum ich das Icon nicht verwenden kann.

[Writing Bull]

Erklär mir lieber mal warum ich das Icon nicht verwenden kann.

Keine Ahnung! Ich weiß es nicht.

Achtung Spoiler:

Okay, eigentlich sollte man sowas nicht erklären, denn dann wird's langweilig - aber ich mach's mal dennoch, um einem möglichen Verärgertsein vorzubeugen: Wenn du schreibst "Ich sollte nicht immer so verallgemeinern", dann enthält dieser Satz schon wieder eine neue Verallgemeinerung (nämlich dass du immer verallgemeinern würdest). Womit dein guter Vorsatz schon in dem Augenblick ad acta gelegt war, als du ihn ausgesprochen hast.

[RAB]

Hallo TAC-Team,

für Icons in allen notwendigen Formaten inkl. Transparenzen empfielt sich die Freeware IcoFX.
Hier kann man es runterladen: http://www.chip.de/downloads/IcoFX_28266149.html

[Writing Bull]

für Icons in allen notwendigen Formaten inkl. Transparenzen empfielt sich die Freeware IcoFX.

Danke dir für den Tipp, RAB! Und schön, dich hier noch mal wiederzusehen.

die Schrift der Titelgrafik ein wenig klein geraten. Ich zumindest habe Mühe da etwas zu erkennen.

Ich hänge dir mal eine andere Version für die Titelleiste an. Immer noch der TAC-Schriftzug, jetzt aber nur noch als Ausschnitt aus unserem Logo und zudem mit verstärkten Kontrasten und grelleren Farben. Falls dir das nicht gefällt, würde ich vom Schriftzug als Motiv ablassen und mir etwas ganz anderes ausdenken.

Ich habe das Icon noch mal etwas verbessert und schwarz umrahmt:

Achtung Spoiler:

Ich finde mit etwas Abstand jetzt meine "Verbesserung", bei der ich das Icon schwarz umrandet hatte, misslungen. Der Himmel sollte grenzenlos bleiben. Das heißt, meines Erachtens sollten wir es hierbei (Icon in der Mitte) belassen.

Es sei denn, jemand anderes möchte mal sein Glück versuchen und eine Alternative basteln ...

[Writing Bull]

Ronnar, die Premiere des Installers rückt näher ...

Übernächsten Samstag (17.12.) mache ich mich daran, TAC 2.02c als Weihnachtsgeschenk für unsere Community zu verpacken. Prima wäre, wenn du mir rechtzeitig dafür alles bereitstellen könntest.

Ich vermute, ich brauche ein Installer-Programm und zudem die von dir vorbereiteten dazu passenden Dateien? Schön wäre, wenn du mir erklären könntest, was ich daran ändern muss, wenn ich diese Dateien für ein neues Release verändere und anpasse. Wenn du magst, erklär das ruhig hier an Ort und Stelle - dann bekommen auch andere Interessierte ein kleines Tutorial für ihre eigenen kommenden Releases (z.B. von Szenarien und ModMods)!

[Ronnar]

Mal sehen, ich sollte am Wochenende ein Paket für dich zusammenstellen können. Du müsstest dann nur noch Pfade anpassen und die Grafiken bereitlegen.

Ab 15.12. bin ich bis Jahresende nicht mehr verfügbar, da spiele ich hoffentlich SWTOR in jeder freien Minute.

[Ronnar]

TAC Installer mit NSIS erstellen

1. NSIS 2.46 herunter laden und installieren http://nsis.sourceforge.net/Download
2. Geeigneten Texteditor installieren (Notepad++ unterstützt auch die NSIS Syntax, siehe unter -> Sprachen -> N -> NSIS)
3. NSIS 2.46 enthält normalerweise auch das Modern UI 2 Plugin. Das ist wichtig, denn ich verwende die vordefinierten Bildschirme aus Modern UI. Eigene zu definieren ist auch möglich, aber aufwändig. Prüfen: Im Ordner \Program Files (x86)\NSIS\Include muss eine Datei MUI2.nsh vorhanden sein.
4. An den vordefinierten Seiten aus Modern UI habe ich eine Änderung am Willkommensbildschirm vorgenommen. Aus dem Anhang bitte die Datei Welcome.nsh in den Ordner C:\Program Files (x86)\NSIS\Contrib\Modern UI 2\Pages kopieren. Eine Sicherheitskopie vorher anlegen kann nicht schaden!
5. Einen Ordner für den TAC Installer anlegen (Speicherort ist egal) und dort die anderen Dateien aus dem Anhang entpacken:

• TAC_Installer.nsi - das eigentliche Installerskript
• Installer_Titelleiste_v.03.bmp - Titelgrafik
• Installer_Willkommen_v_01.bmp - Grafik für Startbildschirm
• TAC_Logo.bmp - Startgrafik
• TAC_License_EN.txt - Copyright-Text Englisch
• TAC_License_DE.txt - Copyright-Text Deutsch

Die Grafiken kannst du jederzeit noch austauschen. Auch solltest du das von dir erstellte Programmicon für TAC in diesen Ordner legen.

Ich werde noch ein paar Erklärungen anhängen, wie das Installerskript angepasst werden kann.

[Ronnar]

Allgemeine Erläuterungen zu NSIS-Skripten:

• Mit ; werden Zeilen kommentiert. Ich habe an einigen Stellen Optionen auskommentiert, diese können ganz einfach aktiviert werden, in dem man das ; löscht.
• In NSIS werden zuerst Bildschirme und deren Inhalte definiert (!define ...), danach aufgerufen (!insertmacro). Dabei verwende ich vordefinierte Bildschirme, die nur noch angepasst werden. Das Grundgerüst ist fest vorgegeben.
• Die eigentlich zu installierenden Dateien werden in Sections angegeben. Jede Section entspricht dabei einer Installationsauswahl.

Und hier Schritt für Schritt das Installerskript:

;NSIS Modern User Interface
;TAC Installer
;Written by Ronnar
;--------------------------------
;Include Modern UI
  !include "MUI2.nsh"
;--------------------------------
;General
  ;Name and file
  Name "The Authentic Colonization"
  OutFile "TAC_Setup.exe"
  ;Default installation folder
  InstallDir "$DOCUMENTS\My Games\Sid Meier's Civilization IV Colonization\MODS\TAC-Installer Test"
  ;Get installation folder from registry if available
  InstallDirRegKey HKCU "Software\TAC" ""
 
  ;Request application privileges for Windows Vista
  RequestExecutionLevel user 

4 Einstellmöglichkeiten im ersten Abschnitt:

• Name => Name unserer Anwendung
• OutFile => Dateiname des erzeugten Installers. Hier sollte man vielleicht noch die Versionsnummer jeweils in den Dateinamen einfügen
• InstallDir => Das Standardinstallationsverzeichnis. Den letzten Teil "TAC-Installer Test" müsste man dann jeweils anpassen, z.B. "TAC 2.02c"
• InstallDirRegKey => Wir legen einen Registryschlüssel fest. Den können wir später nutzen, um das Installationsverzeichnis für TAC zu speichern und auszulesen

;--------------------------------
;Variables
  Var StartMenuFolder
  Var ColPath
  Var ColPath2
;--------------------------------
;Interface Settings
  !define MUI_ABORTWARNING
  !define MUI_UNABORTWARNING
  !define MUI_HEADERIMAGE
  !define MUI_HEADERIMAGE_RIGHT
  !define MUI_HEADERIMAGE_BITMAP_NOSTRETCH
  !define MUI_HEADERIMAGE_BITMAP "Installer_Titelleiste_v.03.bmp"
  !define MUI_HEADERIMAGE_UNBITMAP "Installer_Titelleiste_v.03.bmp"
  !define MUI_WELCOMEFINISHPAGE_BITMAP "Installer_Willkommen_v_01.bmp"
  !define MUI_UNWELCOMEFINISHPAGE_BITMAP "Installer_Willkommen_v_01.bmp"
  !define MUI_COMPONENTSPAGE_SMALLDESC
  ;!define MUI_LICENSEPAGE_CHECKBOX
  !define MUI_WELCOMEPAGE_TEXT $(WLC_TXT) 

In diesem Abschnitt werden Variable definiert und Einstellungen für die verschiedenen Bildschirme gemacht


Einstellmöglichkeiten:

• !define MUI_HEADERIMAGE_BITMAP => Grafik für die Titelleiste
• !define MUI_WELCOMEFINISHPAGE_BITMAP => Grafik für die Startseite
• ;!define MUI_LICENSEPAGE_CHECKBOX => Auskommentiert. Wenn aktiv, wird auf der Lizenzseite ein Zustimmungshaken erforderlich-
• !define MUI_WELCOMEPAGE_TEXT $(WLC_TXT) => Text für die Startseite. $(WLC_TEXT) ist eine sprachabhängige Variable und wird weiter unten dann mit Text gefüllt.

[Ronnar]

;--------------------------------
;Pages
  !insertmacro MUI_PAGE_WELCOME
  !insertmacro MUI_PAGE_LICENSE "$(MUILicense)"
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_DIRECTORY
  ;Start Menu Folder Page Configuration
  !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU" 
  !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\TAC" 
  !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "TAC"
 
  !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
 
  !insertmacro MUI_PAGE_INSTFILES
 
    !define MUI_FINISHPAGE_NOAUTOCLOSE
    !define MUI_FINISHPAGE_RUN
    ;!define MUI_FINISHPAGE_RUN_NOTCHECKED
    !define MUI_FINISHPAGE_RUN_TEXT $(Shortcut_TXT)
 !define MUI_FINISHPAGE_RUN_FUNCTION "LaunchLink"
    ;!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
    !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\ReadMe TAC 2.02b_inoffiziell.txt"
 !define MUI_FINISHPAGE_LINK "TAC Forum http://www.civforum.de/"
 !define MUI_FINISHPAGE_LINK_LOCATION "http://www.civforum.de/forumdisplay.php?f=283"
  !insertmacro MUI_PAGE_FINISH
  !insertmacro MUI_UNPAGE_WELCOME
  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
  !insertmacro MUI_UNPAGE_FINISH
;--------------------------------
;Languages
  !insertmacro MUI_LANGUAGE "English"
  !insertmacro MUI_LANGUAGE "German" 

In diesem Abschnitt werden die verschiedenen Seiten aufgerufen

• Startseite
• Lizenzbedingungen
• zu installierende Komponenten
• Installationsverzeichnis
• Schlußseite

Seiten die mit UN* beginnen sind für den Uninstaller, werden also für die Deinstallation von TAC genutzt.

• !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\ReadMe TAC 2.02b_inoffiziell.txt" => Einbinden der ReadMe-Datei in den Installer. Dateiname muss angepasst werden
• !define MUI_FINISHPAGE_LINK "TAC Forum http://www.civforum.de/" => Link zum Forum (Anzeige)
• !define MUI_FINISHPAGE_LINK_LOCATION "http://www.civforum.de/forumdisplay.php?f=283" => Link zum Forum (tatsächlicher Link)

Im Languages Abschnitt wird festgelegt, welche Sprachen der Installer unterstützt. Gepflegt habe ich nur Deutsch und Englisch, aber das ist beliebig erweiterbar. Die Bildschirme sind in mehr als 20 Sprachen verfügbar.

[Ronnar]

;Installer Sections
SectionGroup /e "!The Authentic Colonization" TAC
Section $(TAC_TXT) TACD
  SetOutPath "$INSTDIR"
  ;ADD YOUR OWN FILES HERE...
  File "C:\Program Files (x86)\NSIS\TAC-Installer\TAC_license_DE.txt"
  File "C:\Program Files (x86)\NSIS\TAC-Installer\ReadMe TAC 2.02b_inoffiziell.txt"
  File "C:\Program Files (x86)\NSIS\TAC-Installer\Desktop_Icon_Soldat_1.ico"
  ;Store installation folder
  WriteRegStr HKCU "Software\TAC" "" $INSTDIR
  ;Create uninstaller
  WriteUninstaller "$INSTDIR\Uninstall.exe"
  !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 
    ;Create shortcuts
    CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
    CreateShortCut "$SMPROGRAMS\$StartMenuFolder\The Authentic Colonization.lnk"  "$ColPath" "mod=\TAC 2.02b_inoffiziell" "$INSTDIR\Desktop_Icon_Soldat_1.ico"
    CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk" "$INSTDIR\Uninstall.exe"
 
  !insertmacro MUI_STARTMENU_WRITE_END
  SetOutPath "$INSTDIR" 
SectionEnd
Section /o $(SOURCE_TXT) Source
  SetOutPath "$INSTDIR\TAC Dokumentation\DLL"
  File "C:\Users\Ronnar\Documents\My Games\Sid Meier's Civilization IV Colonization\MODS\TAC 2.02b_inoffiziell\TAC Dokumentation\DLL\TAC Dokumentation DLL 15.05.2010.xls"
  SetOutPath "$INSTDIR\TAC Dokumentation\"
  File /r "C:\Users\Ronnar\Documents\My Games\Sid Meier's Civilization IV Colonization\MODS\TAC 2.02b_inoffiziell\TAC Dokumentation\Dokumentation Events"
SectionEnd
SectionGroupEnd 

Der eigentlich wichtigste Teil des Skript, hier werden die zu installierenden Komponenten und die enthaltenen Dateien festgelegt.

Eine Komponente beginnt mit Section und endet mit SectionEnd. Im Beispiel hätten wir eine für TAC und eine für die Dokumentation.

Es gibt eigentlich 2 Möglichkeiten:

• Dateien einzeln auflisten, z.B. File "C:\Program Files (x86)\NSIS\TAC-Installer\TAC_license_DE.txt"
• Ganze Verzeichnisse + Unterverzeichnisse auf einmal aufnehmen: Mit /r werden alle Dateien + Unterverzeichnisse gepackt, z.B. File /r "C:\Users\Ronnar\Documents\My Games\Sid Meier's Civilization IV Colonization\MODS\TAC 2.02b_inoffiziell\TAC Dokumentation\Dokumentation Events"

Ich rate davon ab, das gesamte TAC-Verzeichnis auf einmal zu verpacken (das kann bei Fehlern mit dem Pfad Probleme mit dem Uninstaller machen), aber z.B. das folgende Beispiel würde das komplette Assets im Installer verpacken. SetOutPath legt fest, wohin die Dateien bei der Installation entpackt werden sollen.

SetOutPath "$INSTDIR\Assets"
File /r "C:\Users\Ronnar\Documents\My Games\Sid Meier's Civilization IV Colonization\MODS\TAC 2.02b_inoffiziell\Assets" 

CreateShortCut kann Einträge im Startmenu für TAC machen. Hier wäre der mod= Parameter anzupassen und das Icon

[Ronnar]

;--------------------------------
;Descriptions
  ;Language strings
 
  LangString DESC_TACD ${LANG_ENGLISH} "The Authentic Colonisation game mod files"
  LangString DESC_TACD ${LANG_GERMAN} "The Authentic Colonisation - Spieldateien der Modifikation"
  LangString DESC_TAC ${LANG_ENGLISH} "The Authentic Colonisation"
  LangString DESC_TAC ${LANG_GERMAN} "The Authentic Colonisation"
  LangString DESC_Source ${LANG_ENGLISH} "Documentation for modders including DLL source and detailed description of settings and events"
  LangString DESC_Source ${LANG_GERMAN} "Dokumentation für Modder mit DLL Quelldateien und detaillierter Beschreibung vieler Einstellungen und Events"
  LangString DESC_Documentation ${LANG_ENGLISH} "Documentation for modders including event construction kit and detailed description of settings"
  LangString DESC_Documentation ${LANG_GERMAN} "Dokumentation für Modder mit Eventbaukasten und detaillierter Beschreibung vieler Einstellungen"
  LangString WLC_TXT ${LANG_ENGLISH} "This wizard will guide you through the installation of The Authentic Colonization ('TAC')$\r$\n$\r$\nTAC is a modification of 'Sid Meier's Civilization IV Colonization'. Colonization has to be installed befoer TAC can be installed or played. During the TAC installation, no original files will be replaced.$\r$\n$\r$\nIn order for TAC to run correctly, the original game has to be updated to version 1.01f with the official patch. We recommend to manually install the patch instead of using the automatic update feature. Patch Download: http://www.firaxis.com/downloads/Patch/ ColonizationPatch1.01f.exe"
  LangString WLC_TXT ${LANG_GERMAN} "Dieser Assistent wird Sie durch die Installation von The Authentic Colonization ('TAC') begleiten.$\r$\n$\r$\nTAC ist eine Modifikation von 'Sid Meier's Civilization IV Colonization'. Dieses Spiel muss bereits installiert sein, um TAC installieren und spielen zu können. Bei der TAC-Installation werden keine Originaldateien von Colonization überschrieben.$\r$\n$\r$\nDamit TAC fehlerfrei gespielt werden kann, muss zunächst das Originalspiel mit dem offiziellen Patch auf die Version 1.01f aktualisiert werden. Wir empfehlen, den Patch manuell zu installieren und nicht die automatische Updatefunktion zu verwenden. Patch Download: http://www.firaxis.com/downloads/Patch/ ColonizationPatch1.01f.exe"
  LangString TAC_TXT ${LANG_ENGLISH} "The Authentic Colonisation - Game Files"
  LangString TAC_TXT ${LANG_GERMAN} "The Authentic Colonisation - Spieldateien"
  LangString Source_TXT ${LANG_ENGLISH} "Documentation for Modders"
  LangString Source_TXT ${LANG_GERMAN} "Dokumentation für Modder"
  LangString Shortcut_TXT ${LANG_ENGLISH} "Create TAC shortcut on desktop"
  LangString Shortcut_TXT ${LANG_GERMAN} "TAC Shortcut auf dem Desktop anlegen"
  
  LicenseLangString MUILicense ${LANG_ENGLISH} "TAC_License_EN.txt"
  LicenseLangString MUILicense ${LANG_GERMAN} "TAC_License_DE.txt"
  ;Assign language strings to sections
  !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
    !insertmacro MUI_DESCRIPTION_TEXT ${TAC} $(DESC_TAC)
    !insertmacro MUI_DESCRIPTION_TEXT ${TACD} $(DESC_TACD)
    !insertmacro MUI_DESCRIPTION_TEXT ${Source} $(DESC_Source)
    ;!insertmacro MUI_DESCRIPTION_TEXT ${Documentation} $(DESC_Documentation)
  !insertmacro MUI_FUNCTION_DESCRIPTION_END 

Dieser Abschnitt enthält eigentlich nur die Textbausteine + Übersetzungen. Die Texte müssen dann bei Bedarf angepasst werden.
Bei LicenseLangString muss der Pfad zu den Lizenzbedingungen angegeben werden. Im Beispiel liegen die Lizenzbedingungen im selben Verzeichnis wie das NSIS-Skript. Sonst müsste der Dateiname um den Pfad ergänzt werden.

[Ronnar]

;--------------------------------
;Uninstaller Section
Section "Uninstall"
  ;ADD YOUR OWN FILES HERE...
  Delete "$INSTDIR\Uninstall.exe"
  Delete "$INSTDIR\ReadMe TAC 2.02b_inoffiziell.txt"
  Delete "$INSTDIR\TAC_License_DE.txt"
  Delete "$INSTDIR\TAC Dokumentation\DLL\*.*"
  Delete "$INSTDIR\TAC Dokumentation\Dokumentation Events\*.*"
  RMDir "$INSTDIR\TAC Dokumentation\DLL"
  RMDir "$INSTDIR\TAC Dokumentation\Dokumentation Events"
  RMDir "$INSTDIR\TAC Dokumentation"
  RMDir "$INSTDIR"
 
  !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 
  Delete "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk"
  Delete "$SMPROGRAMS\$StartMenuFolder\The Authentic Colonization.lnk"
  RMDir "$SMPROGRAMS\$StartMenuFolder"
  DeleteRegKey /ifempty HKCU "Software\TAC"
SectionEnd 

Dieser Abschnitt schreibt einen Uninstaller, der TAC auch wieder löschen kann. Von der Festplatte und aus dem Startmenu.
Dateien und Verzeichnisse sollten natürlich genau denen entsprechen, die man im Installer-Abschnitt vorher auch installiert hat. Achtung, Fehler in diesem Bereich können schonmal falsche Verzeichnisse oder die ganze Festplatte löschen. Also erst denken, dann schreiben, nochmal genau durchlesen, dann testen Rekursives Löschen (Parameter /r) kann ich aus Sicherheitsgründen nicht empfehlen, es sollten einzelne Unterverzeichnisse wie im Beispiel gelöscht werden.

;--------------------------------
Function .onInit
 
  # the plugins dir is automatically deleted when the installer exits
 InitPluginsDir
 File /oname=$PLUGINSDIR\splash.bmp "TAC_Logo.bmp"
 
 splash::show 1000 $PLUGINSDIR\splash
 Pop $0 ; $0 has '1' if the user closed the splash screen early,
   ; '0' if everything closed normally, and '-1' if some error occurred.
 !insertmacro MUI_LANGDLL_DISPLAY
 
 ReadRegStr $ColPath HKLM "SOFTWARE\Classes\ColonizationSave\DefaultIcon" ""
 StrCpy $ColPath $ColPath -2
FunctionEnd
Function LaunchLink
 StrCpy $ColPath2 $ColPath -16
 SetOutPath "$ColPath2"
 CreateShortCut "$DESKTOP\The Authentic Colonization.lnk"  "$ColPath" "mod=\TAC 2.02b_inoffiziell" "$INSTDIR\Desktop_Icon_Soldat_1.ico"
 ;ExecShell "" "$DESKTOP\The Authentic Colonization.lnk"
FunctionEnd 

Zwei kleine Funktionen:
Die erste zeigt beim Start kurz unser TAC-Logo an. File /oname=$PLUGINSDIR\splash.bmp "TAC_Logo.bmp" muss abgeändert werden, wenn das Logo nicht im selben Verzeichnis wie die Skriptdatei liegt.
Die zweite erstellt auf dem Desktop eine Verknüpfung, wenn der User das auswählt. Die Parameter "mod=\TAC 2.02b_inoffiziell" "$INSTDIR\Desktop_Icon_Soldat_1.ico" müssen entsprechend angepasst werden.

So, das war es eigentlich. Viel Spaß damit WB

[Writing Bull]

Puh! Erschlagend. Das ist ja viel komplexer und komplizierter als der Installer, den ich bislang benutzt hatte. Im Gegenzug erhält man natürlich einen größeren Funktionsumfang ...

Danke, Ronnar!